Excel中的多条件查询，方法非常多，不知道你掌握了哪一种！

下图中，我们要根据E列的品牌和F列的产品名称在A1:C8表中找到对应的销量。

之前跟大家介绍了很多方法，但都是关于公式的，今天跟大家介绍一种不用公式，也可以进行多条件查询的方法！

先跟大家回顾一下用公式，有哪些方法？

一、VLOOKUP IF

下图中G2单元格的公式等于：=VLOOKUP(E2&F2,IF({1,0},$A$2:$A$8&$B$2:$B$8,$C$2:$C$8),2,0)。该公式为数组公式，输入完之后需要按“Ctrl Shift Enter”结束公式。

二、LOOKUP

下图中G2单元格公式等于：

=LOOKUP(1,0/(($A$2:$A$8=E2)*($B$2:$B$8=F2)),$C$2:$C$8)。

或者：

=LOOKUP(1,0/(($A$1:$A$8&$B$1:$B$8)=(E2&F2)),$C$1:$C$8)。

或者：

=LOOKUP(1,1/((($A$1:$A$8=E2) ($B$1:$B$8=F2))=2),$C$1:$C$8)。

三、SUMPRODUCT

下图中G2单元格公式等于：

=SUMPRODUCT(($A$2:$A$8=E2)*($B$2:$B$8=F2)*$C$2:$C$8)。

四、SUM

下图中G2单元格的公式等于：

=SUM(($A$2:$A$8=E2)*($B$2:$B$8=F2)*$C$2:$C$8)，该公式为数组公式，输入完之后需要按“Ctrl Shift Enter”结束公式。

五、SUM IF

下图中G2单元格的公式等于：

=SUM(IF($A$2:$A$8=E2,IF($B$2:$B$8=F2,$C$2:$C$8,0),0))，该公式为数组公式，输入完之后需要按“Ctrl Shift Enter”结束公式。

六、VLOOKUP CHOOSE TRANSPOSE

下图中G2单元格的公式等于：=VLOOKUP(E2&F2,CHOOSE(TRANSPOSE(ROW($1:$2)),$A$2:$A$8&$B$2:$B$8,$C$2:$C$8),2,0)，该公式为数组公式，输入完之后需要按“Ctrl Shift Enter”结束公式。

七、VLOOKUP CHOOSE

下图中G2单元格的公式等于：

=VLOOKUP(E2&F2,CHOOSE({1,2},$A$2:$A$8&$B$2:$B$8,$B$2:$C$8),2,0)，该公式为数组公式，输入完之后需要按“Ctrl Shift Enter”结束公式。

八、HLOOKUP CHOOSE TRANSPOSE

下图中G2单元格的公式等于：

=HLOOKUP(E2&F2,TRANSPOSE(CHOOSE({1,2},$A$2:$A$8&$B$2:$B$8,$B$2:$C$8)),2,0)，该公式为数组公式，输入完之后需要按“Ctrl Shift Enter”结束公式。

九、INDEX MATCH

下图中G2单元格的公式等于：

=INDEX($C$1:$C$8,MATCH(E2&F2,$A$1:$A$8&$B$1:$B$8,0))，该公式为数组公式，输入完之后需要按“Ctrl Shift Enter”结束公式。

或者：

=INDEX($C$1:$C$8,MATCH(1,(E2=$A$1:$A$8)*(F2=$B$1:$B$8),0))，该公式为数组公式，输入完之后需要按“Ctrl Shift Enter”结束公式。

十、OFFSET MATCH

下图中G2单元格的公式等于：

=OFFSET($C$1,MATCH(E2&F2,$A$2:$A$8&$B$2:$B$8,0),)，该公式为数组公式，输入完之后需要按“Ctrl Shift Enter”结束公式。

十一、INDIRECT MATCH

下图中G2单元格的公式等于：

=INDIRECT("C"&MATCH(E2&F2,$A$1:$A$8&$B$1:$B$8,0))，该公式为数组公式，输入完之后需要按“Ctrl Shift Enter”结束公式。

十二、SUMIFS

下图中G2单元格的公式等于：

=SUMIFS($C$2:$C$8,$A$2:$A$8,E2,$B$2:$B$8,F2)。

十三、MAX

下图中G2单元格的公式等于：

=MAX(($A$2:$A$8=E2)*($B$2:$B$8=F2)*$C$2:$C$8)，该公式为数组公式，输入完之后需要按“Ctrl Shift Enter”结束公式。

十四、MIN IF

下图中G2单元格的公式等于：

=MIN(IF(($A$2:$A$8=E2)*($B$2:$B$8=F2),$C$2:$C$8))，该公式为数组公式，输入完之后需要按“Ctrl Shift Enter”结束公式。

以上这些方法，在之前的文章也有跟大家详细讲过，如果公式有不懂的地方，可以去看看之前的文章。

下面，跟大家讲不用公式，怎样进行多条件查询？

方法是：“高级筛选”。使用该方法，需要注意下面3点：

数据列表区域和条件区域的标题必须是相同的。
在条件区域中，品牌的先后顺序要和数据列表区域中出现的先后顺序一致。
此方法不能随着数据变化自动更新，如果需要数据自动更新，请使用公式。

具体操作步骤如下：

1、单击数据区域内任意一个单元格，点击菜单栏的“数据”选项卡，在“排序和筛选”工具组中点击“高级”。

2、弹出“高级筛选”对话框，“方式”选择“将筛选结果复制到其他位置”，“条件区域”选择“E1:F4”单元格区域，“复制到”选择“G1”单元格，点击“确定”按钮。

3、结果如下图所示。

4、动图演示如下。

除了使用“高级筛选”，还可以使用“Power Query”，“合并计算”等等。

这篇文章也跟大家讲了15个多条件查询的方法，如果你能够掌握这些函数公式的用法，对于解决其他问题应该难不倒你的了。

上面的公式，如果有不懂的地方，可以在评论区留言或者私信找我哦！

如果您觉得文章不错，请点赞转发分享给更多的人看到，这是对小编的鼓励与支持，谢谢！

excel多条件查找函数（Excel多条件查找数据）

一、VLOOKUP IF

二、LOOKUP

三、SUMPRODUCT

四、SUM

五、SUM IF

六、VLOOKUP CHOOSE TRANSPOSE

七、VLOOKUP CHOOSE

八、HLOOKUP CHOOSE TRANSPOSE

九、INDEX MATCH

十、OFFSET MATCH

十一、INDIRECT MATCH

十二、SUMIFS

十三、MAX

十四、MIN IF

相关推荐